带密码一键部署PE NSIS脚本 直接上代码 自己用更改GUID[ol]Unicode false
!include "LogicLib.nsh"
!include "FileFunc.nsh"
!include MUI2.nsh
!define Password "Password2025"
!define GUID "{566C315E-2697-4E54-83FF-45EDDCFF12B5}"
!define PEGUID "{566C315F-2697-4E54-83FF-45EDDCFF12B5}"
Name "欢迎使用WinPE"
OutFile "WinPE安装程序.exe"
; 界面设置 - 跳过欢迎页面，直接从密码页面开始
!define MUI_CUSTOMFUNCTION_GUIINIT onGUIInit
Page Custom PasswordPageShow PasswordPageLeave
!define MUI_PAGE_CUSTOMFUNCTION_PRE 'CopyFiles'
!define MUI_PAGE_CUSTOMFUNCTION_SHOW MyInstFiles
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_LANGUAGE "SimpChinese"
Icon start.ico
ShowInstDetails nevershow
AutoCloseWindow true
BrandingText "在线一键安装系统"
Caption ""
Function PasswordPageShow
!insertmacro MUI_HEADER_TEXT "输入密码" "安装程序需要一个正确的安装密码才能继续。"
PassDialog::InitDialog /NOUNLOAD Password /HEADINGTEXT "请致电 XXXXXXXXXXX 索取密码。" /GROUPTEXT "密码输入框"
Pop $R0
GetDlgItem $R1 $HWNDPARENT 1
ShowWindow $R1 ${SW_HIDE}
GetDlgItem $R1 $HWNDPARENT 2 ; 取消按钮ID=2
ShowWindow $R1 ${SW_HIDE}
GetDlgItem $R1 $HWNDPARENT 3 ; 后退按钮ID=3
ShowWindow $R1 ${SW_HIDE}
PassDialog::Show
FunctionEnd
Function PasswordPageLeave
Pop $R0
StrCmp $R0 "${Password}" password_correct
MessageBox MB_OK|MB_ICONEXCLAMATION "密码输入错误！请输入正确的安装密码！"
Abort
password_correct:
MessageBox MB_OK|MB_ICONINFORMATION "密码输入正确！请点击$"确定$"继续进行安装！"
FunctionEnd
Section "主程序" SecMain
SetDetailsPrint textonly
DetailPrint "ToDesk正在下载最新PE文件...."
SetDetailsPrint listonly
SetOutPath C:\YXPE
; 本地文件示例；YXPE.7z 文件包括 boot.sdi winpe.wim
; File YXPE.7z
; Nsis7z::ExtractWithDetails "C:\YXPE\YXPE.7z" "文件解压进度 %s..."
; Delete "C:\YXPE\YXPE.7z"
; 网络下载文件
NScurl::http GET "http://down.jywangluo.cn:88/PE/YXPE.7z" "$PLUGINSDIR\YXPE.7z"
Nsis7z::ExtractWithDetails "$PLUGINSDIR\YXPE.7z" "文件解压进度 %s..."
SetFileAttributes "C:\YXPE" HIDDEN
SetDetailsPrint textonly
DetailPrint "添加启动菜单...."
SetDetailsPrint listonly
System::Call "Kernel32::Wow64EnableWow64FsRedirection(i 0)"
nsExec::Exec 'bcdedit /create ${GUID} /device'
nsExec::Exec 'bcdedit /set ${GUID} ramdisksdidevice partition=C:'
nsExec::Exec 'bcdedit /set ${GUID} ramdisksdipath \YXPE\boot.sdi'
nsExec::Exec 'bcdedit /create ${PEGUID} /d "WinPE 网络维护环境" /application osloader'
nsExec::Exec 'bcdedit /set ${PEGUID} device ramdisk=[C:]\YXPE\winpe.wim,${GUID}'
nsExec::Exec 'bcdedit /set ${PEGUID} osdevice ramdisk=[C:]\YXPE\winpe.wim,${GUID}'
ReadEnvStr $0 "firmware_type"
${If} $0 == "UEFI"
nsExec::Exec 'bcdedit /set ${PEGUID} path \windows\system32\boot\winload.efi'
${Else}
nsExec::Exec 'bcdedit /set ${PEGUID} path \windows\system32\boot\winload.exe'
${EndIf}
nsExec::Exec 'bcdedit /set ${PEGUID} locale zh-CN'
nsExec::Exec 'bcdedit /set ${PEGUID} systemroot \windows'
nsExec::Exec 'bcdedit /set ${PEGUID} winpe yes'
nsExec::Exec 'bcdedit /set ${PEGUID} detecthal yes'
nsExec::Exec 'bcdedit /displayorder ${PEGUID} /addlast'
nsExec::Exec 'bcdedit /bootsequence ${PEGUID} /addfirst'
nsExec::Exec 'bcdedit /timeout 10'
MessageBox MB_YESNO "立即重启系统进入PE点是！稍后自行重启点否" IDYES true IDNO false
true:
Reboot
false:
Quit
SectionEnd
Function .onInit
BrandingURL::Unload
FunctionEnd
Function MyInstFiles
GetDlgItem $0 $HWNDPARENT 1 ;下一步
ShowWindow $0 ${SW_HIDE}
GetDlgItem $0 $HWNDPARENT 2 ;取消
ShowWindow $0 ${SW_HIDE}
GetDlgItem $1 $HWNDPARENT 3 ;上一步
ShowWindow $1 ${SW_HIDE}
GetDlgItem $0 $HWNDPARENT 1037
SendMessage $0 ${WM_SETTEXT} 0 "STR: "
GetDlgItem $0 $HWNDPARENT 1038
SendMessage $0 ${WM_SETTEXT} 0 "STR:正在下载最新PE文件，请稍候...."
FunctionEnd
Function 'CopyFiles'
GetDlgItem $R0 $HWNDPARENT 1
System::Call 'user32::GetWindowLong(i $hwndparent,i -16)i.r0'
intop $1 0x80000 ~
intop $0 $0 & $1
System::Call 'user32::SetWindowLong(i $hwndparent,i -16,i $0)i'
FunctionEnd
Function onGUIInit
BrandingURL::Set /NOUNLOAD "0" "0" "255" "http://down.jywangluo.cn:88"
FunctionEnd
[/ol]复制代码
