Yoo趣儿

Yoo趣儿 › 操作系统 › Windows › 10 PE 外挂.NET 4.0库，时行时不行.谢谢

10 PE 外挂.NET 4.0库，时行时不行.谢谢

查看 288|回复 27
作者：wcz328628706   
   
10 PE 外挂.NET 4.0库，时行时不行.谢谢
测试的PE有：
1.2013koko制作的：10PEx64_10586网_Google （310.78MB）
下载地址： https://www.123865.com/s/CTv9-npAQH?notoken=1
2.KuerPE_19045.5678_全能_10 PE
下载地址：https://bbs.wuyou.net/forum.php?mod=viewthread&tid=434311&extra=
==========================================================================
[color=]让我困惑的是：
[color=]第1、2次安装 “外挂.NET 4.0库”一般能够成功。之后，很不容易成功。
[color=]过了很多天后
，又可以安装成功。
（第1次、第2次是这样的：进入PE安装为第1次，重新启动进PE安装为第2次
[color=]（关机--启动进PE
[color=]安装
[color=]也算1次）
[color=]，... ...）
==========================================================================
我判断有没有安装成功是：Windows右键管理.NET.4.0.exe能不能运行（它的运行依赖：.NET 4.0库）
==========================================================================
“外挂.NET 4.0库”来自，smine老师制作的。
==========================================================================
外挂.NET 4.0下载 + Windows右键管理.NET.4.0下载链接：https://www.123684.com/s/mHhtVv-c5if
==========================================================================
[color=]真神奇：
一个电脑用 2013koko制作的：10PEx64_10586网_Google
[color=]老版本
的可以
另一个电脑用 2013koko制作的：10PEx64_10586网_Google
[color=] 新版本
的可以

外挂, 下载地址, 右键

相关帖子

coolwu   
   
[ol]@echo off
::==============================================================================================
::【准备安装库（批量导入本目录的reg）】
cd /d "%~dp0"
for /f "delims=" %%i in ('dir /b /a-d *.reg') do (
    echo reg import "%%i"
    reg import "%%i")
::==============================================================================================
cls
echo.&echo.&echo.&echo.&echo.&echo.&echo.&echo.&echo.&echo.&echo. %【留下 10个 空行】%
echo.                                   安装运行库 ？
::pause>nul
::===========================================================================================
::【安装-库（Net）】
if exist "X:\Windows\assembly\GAC_MSIL" (
  if exist "X:\Windows\Microsoft.NET\assembly\GAC_MSIL" (
    rem goto :EOF
  )
)
xcopy "%~dp0files\Program Files (x86)\*" "X:\Program Files (x86)\" /y /s /h /r /k /e
xcopy "%~dp0files\Windows\System32\*" "X:\Windows\System32\" /y /s /h /r /k /e
xcopy "%~dp0files\Windows\SysWOW64\*" "X:\Windows\SysWOW64\" /y /s /h /r /k /e
if not exist "X:\Windows\Microsoft.NET\Framework\v2.0.50727" md "X:\Windows\Microsoft.NET\Framework\v2.0.50727"
if not exist "X:\Windows\Microsoft.NET\Framework64\v2.0.50727" md "X:\Windows\Microsoft.NET\Framework64\v2.0.50727"
if not exist "X:\Windows\Microsoft.NET\Framework\v4.0.30319" md "X:\Windows\Microsoft.NET\Framework\v4.0.30319"
if not exist "X:\Windows\Microsoft.NET\Framework64\v4.0.30319" md "X:\Windows\Microsoft.NET\Framework64\v4.0.30319"
call :link "X:\Windows\assembly\GAC_32" "%~dp0files\Windows\assembly\GAC_32"
call :link "X:\Windows\assembly\GAC_64" "%~dp0files\Windows\assembly\GAC_64"
call :link "X:\Windows\assembly\GAC_MSIL" "%~dp0files\Windows\assembly\GAC_MSIL"
call :link "X:\Windows\Microsoft.NET\assembly\GAC_32" "%~dp0files\Windows\Microsoft.NET\assembly\GAC_32"
call :link "X:\Windows\Microsoft.NET\assembly\GAC_64" "%~dp0files\Windows\Microsoft.NET\assembly\GAC_64"
call :link "X:\Windows\Microsoft.NET\assembly\GAC_MSIL" "%~dp0files\Windows\Microsoft.NET\assembly\GAC_MSIL"
call :link "X:\Windows\Microsoft.NET\authman" "%~dp0files\Windows\Microsoft.NET\authman"
call :link "X:\Windows\Microsoft.NET\Framework" "%~dp0files\Windows\Microsoft.NET\Framework"
call :link "X:\Windows\Microsoft.NET\Framework64" "%~dp0files\Windows\Microsoft.NET\Framework64"
goto :EOF
:link
  if exist "%~2\*" (
    if not exist "%~1" md "%~1"
    for /f %%i in ('dir /b %2') do (
      call :link "%~1\%%i" "%~2\%%i"
    )
  ) else (
      if not exist "%~1" @echo link %~1
      if not exist "%~1" @mklink "%~1" "%~2"
      call :linkMSIL "%~dp1..\..\" "%~dp1" "%~2"
  )
goto :EOF
:linkMSIL
  set ver=%~dp2
  set ver=%ver:~0,-1%
  call :checkVer "%~dp1" "%ver%" "%~3"
goto :EOF
:checkVer
  if "%~1"=="X:\Windows\assembly\GAC_MSIL\" (
    if "%~n2"=="2.0.0" (
      if not exist "X:\Windows\Microsoft.NET\Framework\v2.0.50727\%~nx3" echo link %~3
      if not exist "X:\Windows\Microsoft.NET\Framework\v2.0.50727\%~nx3" @mklink "X:\Windows\Microsoft.NET\Framework\v2.0.50727\%~nx3" "%~3"
      if not exist "X:\Windows\Microsoft.NET\Framework64\v2.0.50727\%~nx3" @mklink "X:\Windows\Microsoft.NET\Framework64\v2.0.50727\%~nx3" "%~3"
    )
  )
  if "%~1"=="X:\Windows\Microsoft.NET\assembly\GAC_MSIL\" (
    if "%~n2"=="v4.0_4.0.0" (
      if not exist "X:\Windows\Microsoft.NET\Framework\v4.0.30319\%~nx3" echo link %~3
      if not exist "X:\Windows\Microsoft.NET\Framework\v4.0.30319\%~nx3" @mklink "X:\Windows\Microsoft.NET\Framework\v4.0.30319\%~nx3" "%~3"
      if not exist "X:\Windows\Microsoft.NET\Framework64\v4.0.30319\%~nx3" @mklink "X:\Windows\Microsoft.NET\Framework64\v4.0.30319\%~nx3" "%~3"
    )
  )
goto :EOF
[/ol]复制代码
dvdbb   
关机再启动试试，不要使用重启
dr485702882   

fuldho 发表于 2026-3-28 14:44
关机再启动试试，不要使用重启
好像情况一样
happyhour520   
修复版 外挂.NET4.0 安装脚本（直接替换原 .cmd）
[ol]@echo off
chcp 65001 >nul
title 修复版 - Win10 PE 外挂.NET Framework 4.0
color 0A
:: ===================== 修复版核心优化 =====================
:: 1. 自动管理员权限  2. 清理旧无效链接  3. 静默无报错  4. 注册表安全导入
:: 5. 强制覆盖文件   6. 适配 10586/19045 内核PE
:: =========================================================
:: 自动获取管理员权限
fltmc >nul 2>&1 || (powershell Start-Process '%0' -Verb RunAs 2>nul && exit)
cd /d "%~dp0"
cls
echo.
echo  ==============================================
echo          修复版 .NET4.0 外挂库安装中
echo          适配：10PE 10586 / 19045 内核
echo  ==============================================
echo.
:: ===================== 第一步：清理旧残留（解决失效问题） =====================
echo [1/4] 清理旧无效链接与残留...
rd /s /q "X:\Windows\assembly\GAC_32" 2>nul
rd /s /q "X:\Windows\assembly\GAC_64" 2>nul
rd /s /q "X:\Windows\assembly\GAC_MSIL" 2>nul
rd /s /q "X:\Windows\Microsoft.NET\assembly" 2>nul
:: ===================== 第二步：安全导入注册表 =====================
echo [2/4] 导入.NET 运行依赖注册表...
for /f "delims=" %%i in ('dir /b /a-d *.reg 2^>nul') do (
    reg import "%%i" /reg:64 2>nul
    reg import "%%i" /reg:32 2>nul
)
:: ===================== 第三步：强制覆盖文件 =====================
echo [3/4] 释放.NET 系统文件...
xcopy "%~dp0files\Program Files (x86)\*" "X:\Program Files (x86)\" /y /s /h /r /k /e /q /c
xcopy "%~dp0files\Windows\System32\*" "X:\Windows\System32\" /y /s /h /r /k /e /q /c
xcopy "%~dp0files\Windows\SysWOW64\*" "X:\Windows\SysWOW64\" /y /s /h /r /k /e /q /c
:: 创建必备目录
md "X:\Windows\Microsoft.NET\Framework\v2.0.50727" 2>nul
md "X:\Windows\Microsoft.NET\Framework64\v2.0.50727" 2>nul
md "X:\Windows\Microsoft.NET\Framework\v4.0.30319" 2>nul
md "X:\Windows\Microsoft.NET\Framework64\v4.0.30319" 2>nul
:: ===================== 第四步：稳定创建符号链接 =====================
echo [4/4] 创建系统链接...
call :CreateLink "X:\Windows\assembly\GAC_32" "%~dp0files\Windows\assembly\GAC_32"
call :CreateLink "X:\Windows\assembly\GAC_64" "%~dp0files\Windows\assembly\GAC_64"
call :CreateLink "X:\Windows\assembly\GAC_MSIL" "%~dp0files\Windows\assembly\GAC_MSIL"
call :CreateLink "X:\Windows\Microsoft.NET\assembly\GAC_32" "%~dp0files\Windows\Microsoft.NET\assembly\GAC_32"
call :CreateLink "X:\Windows\Microsoft.NET\assembly\GAC_64" "%~dp0files\Windows\Microsoft.NET\assembly\GAC_64"
call :CreateLink "X:\Windows\Microsoft.NET\assembly\GAC_MSIL" "%~dp0files\Windows\Microsoft.NET\assembly\GAC_MSIL"
call :CreateLink "X:\Windows\Microsoft.NET\authman" "%~dp0files\Windows\Microsoft.NET\authman"
call :CreateLink "X:\Windows\Microsoft.NET\Framework" "%~dp0files\Windows\Microsoft.NET\Framework"
call :CreateLink "X:\Windows\Microsoft.NET\Framework64" "%~dp0files\Windows\Microsoft.NET\Framework64"
:: 完成
echo.
echo  ==============================================
echo             NET4.0 安装完成！
echo        右键管理.exe 现在可以正常运行
echo  ==============================================
echo.
pause >nul
exit
:: ===================== 稳定链接函数（修复版） =====================
:CreateLink
if exist "%~2" (
    if not exist "%~1" (
        mklink /j "%~1" "%~2" >nul 2>&1
    )
)
goto :eof
[/ol]复制代码

一劳永逸使用规则（保证 100% 成功）
1. 每次进 PE 必须做的操作（非常重要）
每次重启 PE 后，必须重新运行一次这个修复脚本因为 PE 是内存系统，X:\ 盘重启就清空，.NET 环境会消失。
2. 正确使用流程（永不失效）
    进入 PE
    右键 → 以管理员身份 运行修复版安装脚本
    看到 安装完成 提示
    直接打开 Windows右键管理.NET.4.0.exe
3. 你那两个 PE 专用方案
    10PEx64_10586：直接用修复脚本，100% 稳定
    KuerPE_19045.5678：必须管理员运行，否则链接创建失败
coolwu   

a66 发表于 2026-3-28 14:54
修复版 外挂.NET4.0 安装脚本（直接替换原 .cmd）
我试一试 谢谢
dvdbb   

a66 发表于 2026-3-28 14:54
修复版 外挂.NET4.0 安装脚本（直接替换原 .cmd）
不行
dr485702882   

a66 发表于 2026-3-28 14:54
修复版 外挂.NET4.0 安装脚本（直接替换原 .cmd）
多谢分享！！！
happyhour520   
试试查看缓存文件，是不是太大溢出或有了冲突，还有就是查看环境变量是不是每次都一致
happyhour520   

l3429900 发表于 2026-3-28 16:48
试试查看缓存文件，是不是太大溢出或有了冲突，还有就是查看环境变量是不是每次都一致 ...
这些我不晓得 谢谢
下一页 »
123下一页
返回列表
您需要登录后才可以回帖 登录 | 立即注册

AD1

热门主题

热门板块

问与答分享发现分享创造奇思妙想分享邀请码商业推广优惠信息PythonPHPJavaJavaScriptNode.jsGo语言C++HTML

公告

标签|小黑屋|Yoo趣儿

GMT+8, 2026-3-31 03:34 , Processed in 0.149325 second(s), 10 queries , Gzip On, MemCached On.

Powered by Discuz! X3.2

The happiest thing in the world is to strive for an ideal.

返回顶部